- 1PS提示：因為圖層已鎖定，無法編輯圖層的處理方法
- 2Adobe Illustrator CS5 序列號大全
- 3picacg蘋果版怎么找不到|picacg ios版是不是下架了介紹
- 4ACDsee注冊碼免費分享（含ACDsee18、ACDsee10等版本）
- 5眼萌app怎么色弱測試 眼萌app色弱測試圖文說明教程
- 6蘋果iphone自動時間不準確的多種校正方法
- 7百度安全衛士好用么_百度安全衛士技巧說明
- 8PDF瀏覽器能看3D文件嗎？PDF瀏覽器看3D文件圖文詳細教程
- 9Potato(馬鈴薯聊天)怎么注冊不了|Potato不能注冊處理方法介紹
- 10Potato(土豆聊天)怎么換頭像|Potato app更改頭像方法介紹
- 11ipad版office如何激活? office365激活的圖文說明教程
- 12最新的Adobe Illustrator CS4序列號大全
[摘要]通常，在asp中進行的form表單提交的數據都被寫進數據庫管理系統中去，如果你想要你的數據是方便攜帶的數據，你可以把它寫進一個XML文件中去。這種方法是跨平臺的，因此你所收集的信息不需要進行轉換。為了實現上面的想法，你必須先利用Microsoft XMLDOM建立一個XML文件，Microsoft...
通常，在asp中進行的form表單提交的數據都被寫進數據庫管理系統中去，如果你想要你的數據是方便攜帶的數據，你可以把它寫進一個XML文件中去。這種方法是跨平臺的，因此你所收集的信息不需要進行轉換。為了實現上面的想法，你必須先利用Microsoft XMLDOM建立一個XML文件，Microsoft XMLDOM對象有一個擴展對象庫，它可以創建組成XML文件所需要的元素、屬性、屬性值。
當XMLDOM對象實例化以后，必須對各個元素進行引用來建立XML的結構，下面的例子就是先建立根元素，并把她追加到XML文件中；然后創建各個子元素，并追加元素的屬性值。最后保存為XML文件。
實例化 Microsoft XMLDOM Object: <%
Dim objDom
Dim objRoot
Dim objChild1
Dim objChild2
Dim objPI
Set objDom = Server.CreateObject("Microsoft.XMLDOM")
Set objRoot = objDom.createElement("rootElement")
objDom.appendChild objRoot
Set objChild1 = objDom.createElement("childElement1")
objRoot.appendChild objChild1
Set objChild2 = objDom.createElement("childElement2")
objRoot.appendChild objChild2
Set objPI = objDom.createProcessingInstruction("xml","version='1.0'")
objDom.insertBefore objPI, objDom.childNodes(0)
objDom.Save "c:\MyXMLDoc.xml"
%>
一旦你保存了文件，用IE5+打開后，樣式如下[當然，屬性還沒有被賦值]：
MyXMLDoc.xml: <?xml version="1.0"?>
<rootElement>
<childElement1 />
<childElement2 />
</rootElement>
下面我們來看看怎樣利用這個對象來存儲用戶的輸入信息。
首先建立輸入表單的頁面。
EnterContact.html: <html>
<head>
<title>
通訊信息
</title>
</head>
<body>
<form action="processForm.asp" method="post">
<h3>請輸入您的通訊信息：</h3>
姓 名: <input type="text" id="Name" name="姓名"><br>
性 別: <input type="text" id="sexName" name="性別"><br>
地 址: <input type="text" id="address" name="地址"><br>
工作單位: <input type="text" id="company" name="工作單位"><br>
電 話: <input type="text" id="phone" name="電話"><br>
電子郵件: <input type="text" id="email" name="電子郵件"><br>
<input type="submit" id="btnSub" name="btnSub" value="提交"><br>
</form>
</body>
</html>
然后編寫ASP代碼，遍歷表單元素，并把輸入的信息寫進XML文件。
processForm.asp: <%
'--------------------------------------------------------------------
'函數 "ConvertFormtoXML"接收傳遞的參數。
'strXMLFilePath - XML存放的物理地址。
'strFileName - 要保存的XML文件的名字。
'--------------------------------------------------------------------
Function ConvertFormtoXML(strXMLFilePath, strFileName)
'定義本地變量.
Dim objDom
Dim objRoot
Dim objField
Dim objFieldValue
Dim objattID
Dim objattTabOrder
Dim objPI
Dim x
'實例化Microsoft XMLDOM對象.
Set objDom = server.CreateObject("Microsoft.XMLDOM")
objDom.preserveWhiteSpace = True
'創建XML文檔的根元素contact，并追加到XML文檔中。
Set objRoot = objDom.createElement("通訊錄")
objDom.appendChild objRoot
'遍歷Request對象Form元素的集合。
For x = 1 To Request.Form.Count
If instr(1,Request.Form.Key(x),"btn") = 0 Then
'創建元素 "field".
Set objField = objDom.createElement("field")
'創建屬性 "id".
Set objattID = objDom.createAttribute("id")
'設定id屬性的值等于Form中各元素的值。
objattID.Text = Request.Form.Key(x)
'setAttributeNode 方法把id屬性值追加到field元素。
objField.setAttributeNode objattID
'創建屬性taborder。
Set objattTabOrder = objDom.createAttribute("taborder")
'設定taborder的屬性值
objattTabOrder.Text = x
'把taborder的屬性值追加到field元素中去。
objField.setAttributeNode objattTabOrder
'創建一個新的元素field_value.
Set objFieldValue = objDom.createElement("field_value")
'賦值
objFieldValue.Text = Request.Form(x)
'追加field元素為根元素的子元素。
objRoot.appendChild objField
'追加field_value做為子元素的內容
objField.appendChild objFieldValue
End If
Next
'創建xml聲明
Set objPI = objDom.createProcessingInstruction("xml", "version='1.0' encoding='gb2312'")
'把xml生命追加到xml文檔
objDom.insertBefore objPI, objDom.childNodes(0)
'保存xml文件
objDom.save strXMLFilePath & "\" & strFileName
'釋放所有對象所引用的值
Set objDom = Nothing
Set objRoot = Nothing
Set objField = Nothing
Set objFieldValue = Nothing
Set objattID = Nothing
Set objattTabOrder = Nothing
Set objPI = Nothing
End Function
'發生錯誤時繼續執行
On Error Resume Next
'調用函數ConvertFormtoXML把文件存放到指定的文件目錄和文件名。
ConvertFormtoXML "D:\aspexam","Contact.xml"
'如果發生錯誤，提示用戶，否則報告成功。
If err.number <> 0 then
Response.write("保存form值出現錯誤！��！")
Else
Response.write("提交成功�。�")
End If
%>
用IE5+打開Contact.xml文件.
推薦資訊 總人氣榜
最新教程 本月人氣
- 1JDBC 示例（轉）
- 2Microsoft IIS 真的如此「不安全」嗎？(2)
- 3Beginner with c# 2
- 4用Visual Basic也可以完成“P2P”
- 5用PHP取Select影響行數的方法
- 6Microsoft IIS 真的如此「不安全」嗎？(3)
- 7Java優化性能技巧集錦（2）
- 8測試已經無誤，重新公布的更改后的分頁類，附點說明
- 9Microsoft IIS 真的如此「不安全」嗎？(4)
- 10來遲了，人不多：為什么開發人員對XML感到激動
- 11PHP 開發人員：充實您的 XML 工具箱
- 12在WinForm中使用Web Services 來完成 軟件 自動升級( Auto Update ) (C#)
相關文章
