曾經在網上看到有人說Delphi能夠產生大小只有16k的Win32應用程序，而我自己曾經編寫過的這種可執行文件大小則是在17k左右，因而我一度猜想Delphi恐怕也只能將代碼優化到這種程度了。最近由于測試的目的重新把這個程序寫了一遍，才發現利用一些技巧，還能夠將文件的大小進一步縮減到8.5k。這個程序也能夠顯示Delphi作為類似于Visual C++的、非RAD工具的另一個側面。如果你對此感興趣的話，請看我是如何做到這一點的。



用Delphi生成一個默認的項目，然后用工具欄上的Remove file from Project按鈕，將唯一的窗體(Form1)從項目中刪除。然后選擇View->Project Source命令，打開項目文件，并編輯代碼如下所示：

program MiniApp;



uses

  Windows, Messages;



// {$R *.res}



const

  szAppName : PChar = 'MiniApp';



function WndProc(AWnd:HWND; message:UINT; wp:WPARAM; lp:LPARAM):LRESULT;stdcall;

begin

  Result := 0;

  case message of

    WM_DESTROY:

       PostQuitMessage(0);

    else

       Result := DefWindowProc(AWnd, message, wp, lp);

  end;

end;



var

  wc : WNDCLASS;

  HMainWnd : HWND;

  AMsg : MSG;



begin

  with wc do begin

    style := CS_VREDRAW or CS_HREDRAW;

    lpfnWndProc := @WndProc;

    cbClsExtra := 0;

    cbWndExtra := 0;

    hIcon := LoadIcon(0, IDI_APPLICATION);

    hCursor := LoadCursor(0, IDC_ARROW);

    hbrBackground := GetSysColorBrush(COLOR_WINDOW);

    hInstance := HInstance;

    lpszMenuName := nil;

    lpszClassName := szAppName;

  end;

  RegisterClass(wc);



  HMainWnd := CreateWindow(szAppName,

                           szAppName,

                           WS_OVERLAPPEDWINDOW,

                           Integer(CW_USEDEFAULT), Integer(CW_USEDEFAULT),

                           Integer(CW_USEDEFAULT), Integer(CW_USEDEFAULT),

                           HWND_DESKTOP, 0,

                           HInstance, nil);

  ShowWindow(HMainWnd, CmdShow);

  UpdateWindow(HMainWnd);



  while GetMessage(AMsg, 0, 0, 0) do begin

    TranslateMessage(AMsg);

    DispatchMessage(AMsg);

  end;

end.



其實這些代碼根本就是Win32 SDK中C語言例子程序的翻版，我想沒有必要再對它們作什么解釋了。需要提醒你注意的是：

1．Delphi程序沒有像C程序那樣的WinMain入口，程序的運行就從.DPR文件的begin開始，到與之匹配的end結束。而C程序中傳遞給WinMain的四個參數，在Delphi中則以全局變量的形式定義在System以及SysInit單元中，它們分別是HInstance、HPrevInst、CmdLine和CmdShow（HPrevInst已經沒有意義）。

2．注意我把常量szAppName定義為PChar，而不是常用的String，因為在這么一個簡單的程序中沒有必要使用String的高級功能，這樣可以節省不少空間（大約3-4k）。

3．我把{$R *.res}一句也注釋起來了，這樣可以從文件中剔除冗余的資源，從而節省大約1k左右的空間。

4．程序完成后，打開Project Options對話框，翻到Compiler頁，將Runtime Errors和Debugging分類中的選項全部清除，這樣也可以稍微減小最終文件的大小。



盡管還不能說8.5k一定就是最小的尺寸，不過我猜想這已經非常接近Delphi的極限了。在Visual C++中，很有意思的一點是所有可執行文件的大小都會對齊到4k的邊界，所以在Visual C++中最小的.EXE和最小的.DLL大小都只能達到28k，除非使用一些非常特殊的隱藏編譯開關。盡管Win32中的分頁默認是4k，不過我實在想不通Visual C++把可執行文件的大小也對齊到4k究竟有什么意義？

另外，我手頭還有一套非常非常古老的Turbo Pascal for Windows 1.5，它所編譯出的最小的Windows可執行文件的大小——你肯定無法相信——只有1.75k！當然了，它畢竟只是個Win16程序而已。