- 1PS提示：因為圖層已鎖定，無法編輯圖層的處理方法
- 2picacg蘋果版怎么找不到|picacg ios版是不是下架了介紹
- 3Adobe Illustrator CS5 序列號大全
- 4ACDsee注冊碼免費分享（含ACDsee18、ACDsee10等版本）
- 5Potato(土豆聊天)怎么換頭像|Potato app更改頭像方法介紹
- 6PDF瀏覽器能看3D文件嗎？PDF瀏覽器看3D文件圖文詳細教程
- 7Potato(馬鈴薯聊天)怎么注冊不了|Potato不能注冊處理方法介紹
- 8最新的Adobe Illustrator CS4序列號大全
- 9Intel i7-9700K性能跑分曝光：同代提升約12%
- 10qq郵件是否已讀怎么看 QQ郵箱已經發出去的郵件怎么知道對方是否已經查看
- 11XP系統怎么清除緩存？
- 12Intel Z390主板有望10月8日公布：8核9代酷睿隨后登場
[摘要]Application對象與Session對象 上一講中，我們學習了Request對象的Form數據集合、QueryString數據集合和ServerVariables數據集合。在繼續下面的學習之前...
Application對象與Session對象
上一講中，我們學習了Request對象的Form數據集合、QueryString數據集合和ServerVariables數據集合。在繼續下面的學習之前，建議你先輕松一下，因為接下來要介紹的Application對象相對比較抽象，剛開始理解起來恐怕會不辨東西。切記：當你找不到北時，便不要過多考慮Application對象到底是什么東西？還是一句老話，先學會使用它。
一、了解Application對象。為了提神我們先看一個計數器的例程（你應該運行它以便于理解）
先編輯一個wuf16.htm文件：
<html>
<body>
記錄某個頁面的點擊數示例：<a href="wuf17.asp">wuf17.asp</a>
</body>
</html>
wuf17.asp的代碼如下：
<% @ LANGUAGE = VBScript %>
<% 'wuf17.asp - 記錄某一頁面的訪問數(計數器原理)
Option Explicit
Dim CountWeb
CountWeb = Request.ServerVariables("SCRIPT_NAME")
'這樣保證每個頁面都有一個唯一的變量, 避免混亂
%>
<HTML><BODY>
<%
Response.Write CountWeb & "<Br><Br>" & vbcrlf
Application.Lock '請看講解
Application(CountWeb) = Application(CountWeb) + 1 '累加器,點擊數加1
Application.UnLock
Response.Write "WEB服務器關閉重啟前該頁的點擊總數為: " & Application(CountWeb)
%>
</BODY></HTML>
運行這個程序時，對大部分的人來說，只有一臺機器，既是Web服務器，又是客戶端。那么你只能想象這樣一種境況了：你的這兩個主頁文件放在很遠的Web服務器上，而如潮水般的國內外用戶正通過瀏覽器訪問它們。每個用戶點擊一次，Application(CountWeb) 的值就加1，而且只要存放文件wuf17.asp的服務器沒有關閉，Application(CountWeb)就將一直累加下去。但是注意，如果服務器關閉后重啟，則Application(CountWeb)將重新從0開始計數（我暈，我說我的頁面訪問數怎么老是一位數）。為了避免這種永遠從零開始的計數情況，你必須要在服務器關閉之前將Application(CountWeb)的值保存起來，下次需要時再取出來，就能夠順序累計下去了，具體如何做，且聽N回后分解。
接下來的問題，就是Application.Lock、UnLock是什么意思？剛才我們做了一個假設，大量的用戶正在訪問該頁面，而每一個用戶的點擊都會發生Application(CountWeb)加1，想想看，這樣不就亂套了（什么！想不出，那肯定是你的主頁終日只有你一個人贊助），所以得有個先來后到的規則。當某一用戶訪問該頁面，需要修改Application(CountWeb)的值時，使用Lock方法加鎖，避免其他用戶修改，修改完后，再解鎖。
從上例中您是否已看出，Application對象提供給所有用戶共享信息（Application(CountWeb)），它所面向的是所有用戶（每個用戶的訪問都會導致計數器加1）。Application對象還有兩個事件，Application_OnStart事件和Application_OnEnd事件（您可千萬別暈，這只是面向對象編程語言中起步的概念），使用時語法如下：
<SCRIPT LANGUAGE=VBScript RUNAT=Server>
Sub Application_OnEnd
'當WEB服務器關閉時，將激活Application_OnEnd事件
'也就是程序將執行放在這里的代碼
'因此服務器關閉前我們可以在這里將wuf17.asp中Application(CountWeb)的值
'保存起來，如放在一個文本文件中。
End Sub
Sub Application_OnStart
'當第一個用戶瀏覽ASP網頁時，將激活Application_OnStart事件，而以后其他用戶瀏覽時，就不發生這一事件了
'也就是程序將執行放在這里的代碼
'因此可在這里讀出保存在文本文件中Application(CountWeb)的值。
End Sub
</SCRIPT>
下面通過一個實例來說明如何使用事件，該程序的作用是統計站點所有頁面的總點擊數。
文件wuf18.asp的代碼（站點內其他頁面文件與這個文件類似）：
<% @ LANGUAGE = VBScript %>
<% Option Explicit
'站內所有頁面文件都應包括這句<!--#include file="wuf19.asp"-->%>
<!--#include file="wuf19.asp"-->
<HTML><BODY>
在服務器關閉重啟之前站點所有頁面總點擊數: <%= Application("CountAll") %>
</BODY></HTML>
文件wuf19.asp的代碼：
<% ' wuf19.asp
Application.Lock
Application("CountAll") = Application("CountAll") + 1
Application.UnLock
%>
文件wuf18.asp與wuf19.asp放在同一目錄下。文件global.asa的代碼：
注意：事件處理程序必須以名為"global.asa"的文本文件存盤，而且必須放在虛擬路徑的根目錄下（一般就是與index.htm或default.htm文件放在同一目錄下，例如：以我的機器為例，就絕對路徑而言，global.asa放在c:\InetPub\home下，而wuf18.asp和wuf19.asp放在c:\InetPub\home\asp下），同一虛擬路徑只允許有一個global.asa文件存在。
<SCRIPT LANGUAGE=VBScript RUNAT=Server>
'global.asa - wuf18.asp 在下載包中的文件名為18global.asa，使用時要改名。
Sub Application_OnStart
'當第一個用戶瀏覽網頁時，置計數器初值為0，
'而以后其他用戶瀏覽時，不再執行以下代碼
Application.Lock
Application("CountAll") = 0
Application.UnLock
End Sub
</SCRIPT>
瀏覽wuf18.asp查看運行結果。看來，僅僅學會使用Application對象并不難。
二、認識Session對象。有了前面的Application對象做鋪墊，Session對象就容易多了。它與Application對象類似，只不過是僅僅用來記錄單個用戶的相關信息，它面向單個用戶，因此我們可以使用Session對象存儲某單個用戶的信息。
與Application對象一樣，Session對象也有兩個事件：Session_OnStart事件和Session_OnEnd事件。使用語法與Application對象類似。
值得一提的是，使用Session對象前，必須確認瀏覽器的Cookie功能已啟用（默認設置就可以了）。
下面舉一個實例，文件global.asa的要求同上，因此上例中的global.asa將被本例中的global.asa覆蓋。
<SCRIPT LANGUAGE=VBScript RUNAT=Server>
' global.asa - wuf20.asp 在下載包中文件名為20global.asa
Sub Session_OnStart
Session("In") = Now '函數Now取得當前時間
End Sub
Sub Session_OnEnd
Session("Out") = Now
Application.Lock
Application("Out") = Session("Out")
Application("In") = Session("In")
Application("Out").UnLock
End Sub
</SCRIPT>
文件wuf20.asp：
<%@ Language=VBScript %>
<HTML>
<BODY>
<% 'wuf20.asp
Response.Write "默認Timeout設置:" & Session.Timeout & "分鐘<Br>"
Session.Timeout = 1
Response.Write "您進入本站的時間:" & Session("In") & "<Br>"
Response.Write "請在 1 分鐘后刷新本頁" & "<Br><Br>"
if Not IsEmpty(Application("Out")) then
Response.Write "您上次進入本站的時間:" & Application("In") & "<Br>"
Response.Write "您上次離開本站的時間:" & Application("Out") & "<Br>"
Response.Write "瀏覽時間(分鐘):" &_
Datediff("n",Application("In"),Application("Out")) & "<Br><Br>"
End If
if IsEmpty(Session("Out")) then
Response.Write "刷新前和刷新后Session(""Out"")的值都為空" & "<Br>"
End If
%>
</BODY>
</HTML>
當用戶第一次瀏覽網頁時，發生Session_OnStart事件，程序記錄用戶本次進入網頁的時間，而此時不會發生Session_OnEnd事件，故Application("Out")值為空，程序不會顯示瀏覽時間。
我們知道，Application對象的生存期為第一個用戶瀏覽網頁直至服務器關閉。而Session對象的生存期為用戶第一次瀏覽網頁（會話開始）直至會話結束。那什么時候會話結束呢？具體到本例中，Session.Timeout = 1設置會話超時為1分鐘，即如果長達1分鐘沒有向Web服務器提供請求，則會話超時，導致會話結束，發生Session_OnEnd事件，程序執行Session_OnEnd內的代碼。在這里我們將進入和離開時間分別放入Application("In")和Application("Out")，因為會話結束后，Session對象將不復存在，這點我們在代碼的最后做了驗證。
從這個例程，可以看出：
1． Application對象和Session對象的生存期不同。
2． Session對象是針對單個用戶的，它的值存放在客戶端，其他用戶的瀏覽對該單用戶的Session對象沒有任何影響。單個用戶只能讀寫自己Session對象的值（如：Session("In")）。
3． 注意在Response.Write中顯示雙引號的表示方法：(""Out"")。
4． 特別提醒：該程序沒有實用性，僅供調試用（僅適用于只有一個用戶瀏覽的情況），請思考這是為什么？答案見本文末。
提示：請注意Application對象的特性。
三、一個經典的實例：如何在網頁上顯示在線人數
在下面的例子中，用Application("Online")來存放在線人數，用Application("CountAll")存放總訪問人數。
原理：當一個新用戶瀏覽網頁時，發生Session_OnStart事件，在線人數加1，訪問用戶數也加1。當某用戶離開時，會話超時后會發生Session_OnEnd事件，在線人數減1。
Global.asa代碼如下：
<SCRIPT LANGUAGE=VBScript RUNAT=Server>
' Global.asa - wuf21.asp
Sub Application_OnStart
Application.Lock
'在這里讀出Application("CountAll")的初始值
Application.UnLock
End Sub
Sub Session_OnStart
Application.Lock
Application("Online") = Application("Online") + 1
Application("CountAll") = Application("CountAll") + 1
Application.UnLock
End Sub
Sub Session_OnEnd
Application.Lock
Application("Online") = Application("Online") - 1
Application.UnLock
End Sub
Sub Application_OnEnd
Application.Lock
'應該在這里將Application("CountAll")保存到文件中
Application.UnLock
End Sub
</SCRIPT>
Wuf21.asp代碼如下：
<%@ Language=VBScript %>
<HTML>
<BODY>
<%Session.Timeout = 5%>
<P>在線人數: <%= Application("Online")%></P>
<P>訪問總人數: <%= Application("CountAll")%></P>
</BODY>
</HTML>
請注意將本例程與wuf17.asp對比，后者是計算點擊數，而前者是計算訪問人數。
答案：由于Applicaton對象適用于所有用戶，所以在多用戶的情況下，其他用戶的瀏覽也會改變Application("In")和Application("Out")的值。
標簽：ASP知識講座3
推薦資訊 總人氣榜
最新教程 本月人氣
- 1新官上任，轉貼一篇：Java做一個最容易的通話程序
- 2使用API創建窗體（類似VC的創建過程）
- 3PHP編程：探索字串的奧秘
- 4asp.net高級圖文詳細教程（3）---對象
- 5Java平臺上的CRM系統
- 6釘釘怎么創建企業群組 創建企業群圖文說明教程
- 7美圖秀秀怎么做剪影 美圖秀秀制作剪影圖文說明教程
- 8酷我k歌怎么錄歌 酷我k歌錄歌圖文說明教程
- 9美圖秀秀怎么導入場景 美圖秀秀場景導入圖文說明教程
- 10花生地鐵wifi連不上怎么辦 花生地鐵wifi不能連接處理方法
- 11企業微信公費電話怎么收費 企業微信公費電話收費規范
- 12愛奇藝視頻截圖文件保存在什么地方 愛奇藝視頻截圖保存位置
- 1獵豹瀏覽器搶票不受12306新版驗證碼影響
- 2ios9不越獄怎么恢復短信與照片 ios9不越獄恢復短信與照片圖文說明教程
- 310天學會php之首天
- 4抱抱app怎么玩 抱抱app使用圖文說明教程圖
- 5360手機助手紅包怎么提現 360手機助手紅包提現設置流程
- 6160wifi遠程桌面怎么連接 160wifi遠程桌面連接設置方法
- 7微信PC版1.0.7.33官方下載公布 修好bug優化軟件
- 8手機登12306驗證碼總是出錯處理方法介紹
- 9Linux內核4.2優化了哪一些地方？
- 10linux系統使用命令維護RHCS的方法
- 113天學好ADO之首天
- 12小米note公布會視頻完整版 2015小米note公布會視頻直播
