發送和接收電子郵件，對于某些執行特殊任務的應用程序而言，是一個十分有用的功能。例如，一個監視網絡服務器資源使用情況的工具軟件，如果它具有自動發送電子郵件的功能，那么當它發現服務器的資源使用已經接近事先設定的臨界狀態時，便可以向系統管理員發送一封告警的電子郵件，從而使系統管理員能夠及時地采取措施，以避免重大事故的出現。在Visual Basic中，應用程序可以通過調用微軟公司的MAPI（Messaging Application Programming Interface，消息應用程序編程接口），實現收發電子郵件的功能。筆者將在本文中結合簡單實例，向大家介紹在VB程序中實現電子郵件收發功能的編程方法。

　　 編制具有收發電子郵件功能的VB程序，必須使用Visual Basic 4.0以上的版本，因為只有4.0以上的Visual Basic才帶有兩個實現電子郵件收發功能的核心控件：MAPI會話控件和MAPI消息控件。MAPI會話控件用于建立和控制一個Microsoft Mail會話，MAPI消息控件用于創建和收發郵件消息。此外，程序必須運行在采用遵從MAPI的消息系統（如：Microsoft Exchange、Microsoft Mail、Outlook等）的環境中。

　　在開始編程之前，首先需要將MAPI控件加入VB工具箱。具體操作是：在VB菜單欄中選擇Tools菜單項中的Custom Controls命令，調出"Custom Controls"對話框，在其中的"Available Controls"列表框中選中"Microsoft MAPI Controls"表項，然后按"OK"命令按鈕退出該對話框。此后，工具箱中將新添兩個圖標，這就是MAPI會話控件和MAPI消息控件的圖標。

　　下面，筆者將以兩個簡單的VB程序為例，分別介紹發送郵件和接收郵件的程序編制方法。

　　 郵件發送程序

　 　郵件發送程序的基本處理過程是：根據用戶輸入信息組成郵件，然后使用MAPI消息控件的Send方法將郵件發出。編程步驟如下：

　　1、新建一個VB項目。

　　2、將缺省窗體Form1的Caption屬性設置為"發送郵件"。

　　3、將MAPI控件加入VB工具框。

　　4、在Form1中加入一個MAPI會話控件MAPISession1和一個MAPI消息控件MAPIMessages1。

　　5、在Form1中加入三個文本框控件，將它們的Name屬性分別設置為txtSendTo、txtSubject、txtMessage，并將txtMessage的Multiline屬性設置為True。這三個文本框控件將分別用于填寫郵件的收件人、主題和內容。

　　6、在Form1中加入三個標簽控件，將它們的Caption屬性分別設置為"收件人"、"主題"和"內容"，并將它們放在合適的位置用以標注相應的文本框控件。

　　7、在Form1中加入一個命令按鈕控件，將其Caption屬性和Name屬性分別設置為"發送"和"cmdSend"。

　　8、將下列代碼加入Form1的Form_Load事件：

　　Private Sub Form_Load()
　　MAPISession1.SignOn
　　End Sub  

　　9、將下列代碼加入Form1的Form_Unload事件：

　　Private Sub Form_Unload(Cancel As Integer)
　　MAPISession1.SignOff
　　End Sub  

10、將下列代碼加入cmdSend的Click事件：

　　Private Sub cmdSend_Click()
　　With MAPIMessages1
　　.MsgIndex = -1
　　.RecipDisplayName = txtSendTo.Text
　　.MsgSubject = txtSubject.Text
　　.MsgNoteText = txtMessage.Text
　　.SessionID = MAPISession1.SessionID
　　.Send
　　End With
　　MsgBox "郵件發送完畢！", , "發送郵件"
　　End Sub  

　　在填寫完郵件的收件人、主題和內容后，按"發送"命令按鈕，如果沒有出現運行時錯誤提示，那么就表明郵件已經成功地發往目的地了，否則，請檢查填寫的收件人地址是否準確無誤以及系統中運行的消息系統工作是否正常。

　　郵件接收程序

　　郵件接收程序比郵件發送程序稍微復雜一些。首先需要使用MAPI消息控件的Fetch方法讀取郵件，這個過程將把用戶收件箱中所有未讀郵件全部裝入MAPI消息控件中。然后，檢查MAPI消息控件的MsgCount屬性以確定通過Fetch方法讀取的郵件的總數。接著，可以通過設置MAPI消息控件的MsgIndex屬性來指定具體需要處理哪一封郵件。需要說明的是，MsgIndex屬性值的計數是從0開始的，也就是說，第一封郵件的索引號是0，第二封郵件的索引號是1，依次類推。編程步驟如下：
　　1、新建一個VB項目。
　　2、將缺省窗體Form1的Caption屬性設置為"接收郵件"。

　　3、將MAPI控件加入VB工具框。

　　4、在Form1中加入一個MAPI會話控件MAPISession1和一個MAPI消息控件MAPIMessages1。

　　5、在Form1中加入三個標簽控件和一個文本框控件，將三個標簽控件的Name屬性分別設置為lblMsgDateReceived、lblMsgOrigDisplayName、lblMsgSubject，將文本框控件的Name屬性設置為txtMsgNoteText，并將標簽控件的Caption屬性和文本框控件的Text屬性的內容清空。這四個控件將分別用于顯示郵件的日期、發件人、主題和內容。

　　6、將txtMsgNoteText控件的Locked屬性和Multiline屬性設置為True，ScrollBars屬性設置為2 - Vertical。

　　7、在Form1中再加入四個標簽控件用于標注上述四個控件，將它們的Caption屬性分別設置為"日期"、"發件人"、"主題"、"內容"。

　　8、在Form1中加入一個標簽控件，將其Name屬性設置為lblMsgCount，Caption屬性設置為"第 0 封郵件，總計 0 封郵件"。該控件用于顯示接收的郵件總數以及當前正在處理第幾封郵件。

　　9、在Form1中加入三個命令按鈕控件，將它們的Name屬性分別設置為cmdPrevious、cmdNext、cmdClose，Caption屬性分別設置為"上一封"、"下一封"、"關閉"。



　　10、編寫一個窗體級子例程FetchNewMail：

　　Public Sub FetchNewMail()
　　MAPIMessages1.FetchUnreadOnly = True
　　MAPIMessages1.Fetch
　　End Sub  

　　11、編寫一個窗體級子例程DisplayMessage：

　　Public Sub DisplayMessage()
　　lblMsgCount.Caption = "第 " & _
　　LTrim(Str(MAPIMessages1.MsgIndex + 1)) & " 封郵件，總計 " & _ 　　
　　LTrim(Str(MAPIMessages1.MsgCount)) & " 封郵件"
　　lblMsgDateReceived.Caption = MAPIMessages1.MsgDateReceived
　　txtMsgNoteText.Text = MAPIMessages1.MsgNoteText
　　lblMsgOrigDisplayName.Caption = MAPIMessages1.MsgOrigDisplayName 　　
　　lblMsgSubject.Caption = MAPIMessages1.MsgSubject
　　End Sub  

　　12、將下列代碼加入Form1的Form_Load事件：

　　Private Sub Form_Load()
　　MAPISession1.SignOn
　　MAPIMessages1.SessionID = MAPISession1.SessionID
　　FetchNewMail
　　DisplayMessage
　　End Sub  

　　13、將下列代碼加入cmdPrevious的Click事件：

　　Private Sub cmdPrevious_Click()
　　If MAPIMessages1.MsgIndex > 0 Then
　　MAPIMessages1.MsgIndex = MAPIMessages1.MsgIndex - 1
　　DisplayMessage
　　Else
　　Beep
　　End If
　　End Sub  




　　14、將下列代碼加入cmdNext的Click事件：

　　Private Sub cmdNext_Click()
　　If MAPIMessages1.MsgIndex < MAPIMessages1.MsgCount - 1 Then
　　MAPIMessages1.MsgIndex = MAPIMessages1.MsgIndex + 1
　　DisplayMessage
　　Else
　　Beep
　　End If
　　End Sub  

　　15、將下列代碼加入cmdClose的Click事件：

　　Private Sub cmdClose_Click()
　　Unload Me
　　End Sub  

　　在窗體加載過程中，窗體Load事件中的代碼會讀取新郵件，如果有新郵件，就顯示第一個新郵件。如果有多個新郵件，則可以使用"上一封"和"下一封"命令按鈕前后翻閱。

　　接收郵件

　　本例是讀取用戶收件箱中所有未讀郵件，如果要讀取收件箱中所有的郵件，那么只需在執行Fetch方法之前，將MAPI消息控件的FetchUnreadOnly屬性設置為False。具體接收的郵件是否已經讀過，可以通過MsgRead屬性來判別。如果郵件的正文或附件曾經被瀏覽過，那么該郵件就會自動標記為已讀，不過只瀏覽郵件的主題不會標記該郵件已讀。

　　郵件附件

　　與處理郵件的方式一樣，MAPI也為郵件的附件提供了一個計數器和一個索引。在處理收到的郵件時，可以通過檢查AttachmentCount屬性來確定該郵件攜帶了多少個附件，然后可以通過設置AttachmentIndex屬性依次處理每一個附件。

　　AttachmentIndex的合法取值范圍為0至AttachmentIndex-1。在設置了AttachmentIndex屬性值后，可以讀取附件的下列屬性：

　　AttachmentName：當附件是一個文件時，該屬性用于指定文件的名稱。當附件是一個OLE對象時，該屬性用于指定對象的類型。

　　AttachmentPath：該屬性用于指定做為附件的文件的全路徑名。

　　AttchmentPosition：該屬性用于指定附件在郵件內容部分中的位置。當郵件收發程序顯示郵件內容時，將使用該屬性提供的信息把附件的標志放在合適的位置。

　　AttachmentType：該屬性用于指定附件的類型，其合法取值為三個整數型數值，在VB中分別由下列常量表示：

　　·mapData－附件是一個數據文件
　　·mapEOLE－附件是一個嵌入式OLE對象
　　·mapSOLE－附件是一個靜態OLE對象

　　發送郵件時，上述屬性的使用方法與接收郵件時相同，只不過由讀操作改為寫操作了。值得一提的是AttachmentIndex屬性，發送郵件時可以將其設置為任意值。而AttachmentCount屬性則會自動設置為正確的值，無需人為設置。

　　小結

　　通過分析上述兩個程序的代碼，可以歸納出具有收發電子郵件功能的VB程序的基本流程如下：

　　1、使用MAPI會話控件建立一個郵件會話。

　　2、使用MAPI消息控件進行郵件的處理工作。

　　3、再次使用MAPI會話控件釋放郵件會話。

　　由于上述兩個VB程序只是簡單的示例，因而略去了一些與本文主題關系不大的細節，如錯誤處理等。在編制實用程序時，為了保證程序的可靠性，應該考慮加入這些細節部分。